1: /*
2: * BIRD -- Border Gateway Protocol Configuration
3: *
4: * (c) 2000 Martin Mares <mj@ucw.cz>
5: *
6: * Can be freely distributed and used under the terms of the GNU GPL.
7: */
8:
9: CF_HDR
10:
11: #include "proto/bgp/bgp.h"
12:
13: CF_DEFINES
14:
15: #define BGP_CFG ((struct bgp_config *) this_proto)
16:
17: CF_DECLS
18:
19: CF_KEYWORDS(BGP, LOCAL, NEIGHBOR, AS, HOLD, TIME, CONNECT, RETRY,
20: KEEPALIVE, MULTIHOP, STARTUP, VIA, NEXT, HOP, SELF, DEFAULT,
21: PATH, METRIC, ERROR, START, DELAY, FORGET, WAIT, ENABLE,
22: DISABLE, AFTER, BGP_PATH, BGP_LOCAL_PREF, BGP_MED, BGP_ORIGIN,
23: BGP_NEXT_HOP, BGP_ATOMIC_AGGR, BGP_AGGREGATOR, BGP_COMMUNITY,
24: BGP_EXT_COMMUNITY, SOURCE, ADDRESS, PASSWORD, RR, RS, CLIENT,
25: CLUSTER, ID, AS4, ADVERTISE, IPV4, CAPABILITIES, LIMIT, PASSIVE,
26: PREFER, OLDER, MISSING, LLADDR, DROP, IGNORE, ROUTE, REFRESH,
27: INTERPRET, COMMUNITIES, BGP_ORIGINATOR_ID, BGP_CLUSTER_LIST, IGP,
28: TABLE, GATEWAY, DIRECT, RECURSIVE, MED, TTL, SECURITY, DETERMINISTIC,
29: SECONDARY, ALLOW, BFD, ADD, PATHS, RX, TX, GRACEFUL, RESTART, AWARE,
30: CHECK, LINK, PORT, EXTENDED, MESSAGES, SETKEY, BGP_LARGE_COMMUNITY,
31: LONG, LIVED, STALE)
32:
33: CF_KEYWORDS(CEASE, PREFIX, LIMIT, HIT, ADMINISTRATIVE, SHUTDOWN, RESET, PEER,
34: CONFIGURATION, CHANGE, DECONFIGURED, CONNECTION, REJECTED, COLLISION,
35: OUT, OF, RESOURCES)
36:
37: %type<i> bgp_cease_mask bgp_cease_list bgp_cease_flag
38:
39: CF_GRAMMAR
40:
41: CF_ADDTO(proto, bgp_proto '}' { bgp_check_config(BGP_CFG); } )
42:
43: bgp_proto_start: proto_start BGP {
44: this_proto = proto_config_new(&proto_bgp, $1);
45: BGP_CFG->remote_port = BGP_PORT;
46: BGP_CFG->multihop = -1; /* undefined */
47: BGP_CFG->hold_time = 240;
48: BGP_CFG->initial_hold_time = 240;
49: BGP_CFG->compare_path_lengths = 1;
50: BGP_CFG->igp_metric = 1;
51: BGP_CFG->connect_delay_time = 5;
52: BGP_CFG->connect_retry_time = 120;
53: BGP_CFG->error_amnesia_time = 300;
54: BGP_CFG->error_delay_time_min = 60;
55: BGP_CFG->error_delay_time_max = 300;
56: BGP_CFG->enable_refresh = 1;
57: BGP_CFG->enable_as4 = 1;
58: BGP_CFG->capabilities = 2;
59: BGP_CFG->advertise_ipv4 = 1;
60: BGP_CFG->interpret_communities = 1;
61: BGP_CFG->default_local_pref = 100;
62: BGP_CFG->gr_mode = BGP_GR_AWARE;
63: BGP_CFG->gr_time = 120;
64: BGP_CFG->llgr_mode = -1;
65: BGP_CFG->llgr_time = 3600;
66: BGP_CFG->setkey = 1;
67: }
68: ;
69:
70: bgp_nbr_opts:
71: /* empty */
72: | bgp_nbr_opts PORT expr { BGP_CFG->remote_port = $3; if (($3<1) || ($3>65535)) cf_error("Invalid port number"); }
73: | bgp_nbr_opts AS expr { BGP_CFG->remote_as = $3; }
74: ;
75:
76: bgp_cease_mask:
77: /* true -> all except connection collision */
78: bool { $$ = $1 ? ~(1 << 7) : 0; }
79: | '{' bgp_cease_list '}' { $$ = $2; }
80: ;
81:
82: bgp_cease_list:
83: bgp_cease_flag
84: | bgp_cease_list ',' bgp_cease_flag { $$ = $1 | $3; }
85: ;
86:
87: bgp_cease_flag:
88: CEASE { $$ = 1 << 0; }
89: | PREFIX LIMIT HIT { $$ = 1 << 1; }
90: | ADMINISTRATIVE SHUTDOWN { $$ = 1 << 2; }
91: | PEER DECONFIGURED { $$ = 1 << 3; }
92: | ADMINISTRATIVE RESET { $$ = 1 << 4; }
93: | CONNECTION REJECTED { $$ = 1 << 5; }
94: | CONFIGURATION CHANGE { $$ = 1 << 6; }
95: | CONNECTION COLLISION { $$ = 1 << 7; }
96: | OUT OF RESOURCES { $$ = 1 << 8; }
97: ;
98:
99: bgp_proto:
100: bgp_proto_start proto_name '{'
101: | bgp_proto proto_item ';'
102: | bgp_proto LOCAL AS expr ';' { BGP_CFG->local_as = $4; }
103: | bgp_proto LOCAL ipa AS expr ';' { BGP_CFG->source_addr = $3; BGP_CFG->local_as = $5; }
104: | bgp_proto NEIGHBOR bgp_nbr_opts ';'
105: | bgp_proto NEIGHBOR ipa ipa_scope bgp_nbr_opts ';' {
106: if (ipa_nonzero(BGP_CFG->remote_ip))
107: cf_error("Only one neighbor per BGP instance is allowed");
108: BGP_CFG->remote_ip = $3;
109: if ($4) BGP_CFG->iface = $4;
110: }
111: | bgp_proto INTERFACE TEXT ';' { BGP_CFG->iface = if_get_by_name($3); }
112: | bgp_proto RR CLUSTER ID idval ';' { BGP_CFG->rr_cluster_id = $5; }
113: | bgp_proto RR CLIENT ';' { BGP_CFG->rr_client = 1; }
114: | bgp_proto RS CLIENT ';' { BGP_CFG->rs_client = 1; }
115: | bgp_proto HOLD TIME expr ';' { BGP_CFG->hold_time = $4; }
116: | bgp_proto STARTUP HOLD TIME expr ';' { BGP_CFG->initial_hold_time = $5; }
117: | bgp_proto DIRECT ';' { BGP_CFG->multihop = 0; }
118: | bgp_proto MULTIHOP ';' { BGP_CFG->multihop = 64; }
119: | bgp_proto MULTIHOP expr ';' { BGP_CFG->multihop = $3; if (($3<1) || ($3>255)) cf_error("Multihop must be in range 1-255"); }
120: | bgp_proto NEXT HOP SELF ';' { BGP_CFG->next_hop_self = 1; BGP_CFG->next_hop_keep = 0; }
121: | bgp_proto NEXT HOP KEEP ';' { BGP_CFG->next_hop_keep = 1; BGP_CFG->next_hop_self = 0; }
122: | bgp_proto MISSING LLADDR SELF ';' { BGP_CFG->missing_lladdr = MLL_SELF; }
123: | bgp_proto MISSING LLADDR DROP ';' { BGP_CFG->missing_lladdr = MLL_DROP; }
124: | bgp_proto MISSING LLADDR IGNORE ';' { BGP_CFG->missing_lladdr = MLL_IGNORE; }
125: | bgp_proto GATEWAY DIRECT ';' { BGP_CFG->gw_mode = GW_DIRECT; }
126: | bgp_proto GATEWAY RECURSIVE ';' { BGP_CFG->gw_mode = GW_RECURSIVE; }
127: | bgp_proto PATH METRIC bool ';' { BGP_CFG->compare_path_lengths = $4; }
128: | bgp_proto MED METRIC bool ';' { BGP_CFG->med_metric = $4; }
129: | bgp_proto IGP METRIC bool ';' { BGP_CFG->igp_metric = $4; }
130: | bgp_proto PREFER OLDER bool ';' { BGP_CFG->prefer_older = $4; }
131: | bgp_proto DETERMINISTIC MED bool ';' { BGP_CFG->deterministic_med = $4; }
132: | bgp_proto DEFAULT BGP_MED expr ';' { BGP_CFG->default_med = $4; }
133: | bgp_proto DEFAULT BGP_LOCAL_PREF expr ';' { BGP_CFG->default_local_pref = $4; }
134: | bgp_proto SOURCE ADDRESS ipa ';' { BGP_CFG->source_addr = $4; }
135: | bgp_proto START DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; log(L_WARN "%s: Start delay time option is deprecated, use connect delay time", this_proto->name); }
136: | bgp_proto CONNECT DELAY TIME expr ';' { BGP_CFG->connect_delay_time = $5; }
137: | bgp_proto CONNECT RETRY TIME expr ';' { BGP_CFG->connect_retry_time = $5; }
138: | bgp_proto KEEPALIVE TIME expr ';' { BGP_CFG->keepalive_time = $4; }
139: | bgp_proto ERROR FORGET TIME expr ';' { BGP_CFG->error_amnesia_time = $5; }
140: | bgp_proto ERROR WAIT TIME expr ',' expr ';' { BGP_CFG->error_delay_time_min = $5; BGP_CFG->error_delay_time_max = $7; }
141: | bgp_proto DISABLE AFTER ERROR bool ';' { BGP_CFG->disable_after_error = $5; }
142: | bgp_proto DISABLE AFTER CEASE bgp_cease_mask ';' { BGP_CFG->disable_after_cease = $5; }
143: | bgp_proto ENABLE ROUTE REFRESH bool ';' { BGP_CFG->enable_refresh = $5; }
144: | bgp_proto ENABLE AS4 bool ';' { BGP_CFG->enable_as4 = $4; }
145: | bgp_proto ENABLE EXTENDED MESSAGES bool ';' { BGP_CFG->enable_extended_messages = $5; }
146: | bgp_proto CAPABILITIES bool ';' { BGP_CFG->capabilities = $3; }
147: | bgp_proto ADVERTISE IPV4 bool ';' { BGP_CFG->advertise_ipv4 = $4; }
148: | bgp_proto PASSWORD text ';' { BGP_CFG->password = $3; }
149: | bgp_proto SETKEY bool ';' { BGP_CFG->setkey = $3; }
150: | bgp_proto ROUTE LIMIT expr ';' {
151: this_proto->in_limit = cfg_allocz(sizeof(struct proto_limit));
152: this_proto->in_limit->limit = $4;
153: this_proto->in_limit->action = PLA_RESTART;
154: log(L_WARN "%s: Route limit option is deprecated, use import limit", this_proto->name);
155: }
156: | bgp_proto PASSIVE bool ';' { BGP_CFG->passive = $3; }
157: | bgp_proto INTERPRET COMMUNITIES bool ';' { BGP_CFG->interpret_communities = $4; }
158: | bgp_proto SECONDARY bool ';' { BGP_CFG->secondary = $3; }
159: | bgp_proto ADD PATHS RX ';' { BGP_CFG->add_path = ADD_PATH_RX; }
160: | bgp_proto ADD PATHS TX ';' { BGP_CFG->add_path = ADD_PATH_TX; }
161: | bgp_proto ADD PATHS bool ';' { BGP_CFG->add_path = $4 ? ADD_PATH_FULL : 0; }
162: | bgp_proto ALLOW BGP_LOCAL_PREF bool ';' { BGP_CFG->allow_local_pref = $4; }
163: | bgp_proto ALLOW LOCAL AS ';' { BGP_CFG->allow_local_as = -1; }
164: | bgp_proto ALLOW LOCAL AS expr ';' { BGP_CFG->allow_local_as = $5; }
165: | bgp_proto GRACEFUL RESTART bool ';' { BGP_CFG->gr_mode = $4; }
166: | bgp_proto GRACEFUL RESTART AWARE ';' { BGP_CFG->gr_mode = BGP_GR_AWARE; }
167: | bgp_proto GRACEFUL RESTART TIME expr ';' { BGP_CFG->gr_time = $5; }
168: | bgp_proto LONG LIVED GRACEFUL RESTART bool ';' { BGP_CFG->llgr_mode = $6; }
169: | bgp_proto LONG LIVED GRACEFUL RESTART AWARE ';' { BGP_CFG->llgr_mode = BGP_LLGR_AWARE; }
170: | bgp_proto LONG LIVED STALE TIME expr ';' { BGP_CFG->llgr_time = $6; }
171: | bgp_proto IGP TABLE rtable ';' { BGP_CFG->igp_table = $4; }
172: | bgp_proto TTL SECURITY bool ';' { BGP_CFG->ttl_security = $4; }
173: | bgp_proto CHECK LINK bool ';' { BGP_CFG->check_link = $4; }
174: | bgp_proto BFD bool ';' { BGP_CFG->bfd = $3; cf_check_bfd($3); }
175: | bgp_proto BFD GRACEFUL ';' { BGP_CFG->bfd = BGP_BFD_GRACEFUL; cf_check_bfd(1); }
176: ;
177:
178: CF_ADDTO(dynamic_attr, BGP_ORIGIN
179: { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_ENUM_BGP_ORIGIN, EA_CODE(EAP_BGP, BA_ORIGIN)); })
180: CF_ADDTO(dynamic_attr, BGP_PATH
181: { $$ = f_new_dynamic_attr(EAF_TYPE_AS_PATH, T_PATH, EA_CODE(EAP_BGP, BA_AS_PATH)); })
182: CF_ADDTO(dynamic_attr, BGP_NEXT_HOP
183: { $$ = f_new_dynamic_attr(EAF_TYPE_IP_ADDRESS, T_IP, EA_CODE(EAP_BGP, BA_NEXT_HOP)); })
184: CF_ADDTO(dynamic_attr, BGP_MED
185: { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(EAP_BGP, BA_MULTI_EXIT_DISC)); })
186: CF_ADDTO(dynamic_attr, BGP_LOCAL_PREF
187: { $$ = f_new_dynamic_attr(EAF_TYPE_INT, T_INT, EA_CODE(EAP_BGP, BA_LOCAL_PREF)); })
188: CF_ADDTO(dynamic_attr, BGP_ATOMIC_AGGR
189: { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(EAP_BGP, BA_ATOMIC_AGGR)); })
190: CF_ADDTO(dynamic_attr, BGP_AGGREGATOR
191: { $$ = f_new_dynamic_attr(EAF_TYPE_OPAQUE, T_ENUM_EMPTY, EA_CODE(EAP_BGP, BA_AGGREGATOR)); })
192: CF_ADDTO(dynamic_attr, BGP_COMMUNITY
193: { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(EAP_BGP, BA_COMMUNITY)); })
194: CF_ADDTO(dynamic_attr, BGP_ORIGINATOR_ID
195: { $$ = f_new_dynamic_attr(EAF_TYPE_ROUTER_ID, T_QUAD, EA_CODE(EAP_BGP, BA_ORIGINATOR_ID)); })
196: CF_ADDTO(dynamic_attr, BGP_CLUSTER_LIST
197: { $$ = f_new_dynamic_attr(EAF_TYPE_INT_SET, T_CLIST, EA_CODE(EAP_BGP, BA_CLUSTER_LIST)); })
198: CF_ADDTO(dynamic_attr, BGP_EXT_COMMUNITY
199: { $$ = f_new_dynamic_attr(EAF_TYPE_EC_SET, T_ECLIST, EA_CODE(EAP_BGP, BA_EXT_COMMUNITY)); })
200: CF_ADDTO(dynamic_attr, BGP_LARGE_COMMUNITY
201: { $$ = f_new_dynamic_attr(EAF_TYPE_LC_SET, T_LCLIST, EA_CODE(EAP_BGP, BA_LARGE_COMMUNITY)); })
202:
203:
204:
205: CF_ENUM(T_ENUM_BGP_ORIGIN, ORIGIN_, IGP, EGP, INCOMPLETE)
206:
207: CF_CODE
208:
209: CF_END
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/cvsweb/back.gif){kind=icon}
Return to config.Y CVS log ![[TXT]](/icons/cvsweb/text.gif){kind=icon}
![[DIR]](/icons/cvsweb/dir.gif){kind=icon}
Up to [ELWIX - Embedded LightWeight unIX -] / embedaddon / bird / proto / bgp