Return to configure.ac CVS log

Up to [ELWIX - Embedded LightWeight unIX -] / embedaddon / libiconv

libiconv

    1: dnl Copyright (C) 1999-2009 Free Software Foundation, Inc.
    2: dnl This file is part of the GNU LIBICONV Library.
    3: dnl
    4: dnl The GNU LIBICONV Library is free software; you can redistribute it
    5: dnl and/or modify it under the terms of the GNU Library General Public
    6: dnl License as published by the Free Software Foundation; either version 2
    7: dnl of the License, or (at your option) any later version.
    8: dnl
    9: dnl The GNU LIBICONV Library is distributed in the hope that it will be
   10: dnl useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
   11: dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
   12: dnl Library General Public License for more details.
   13: dnl
   14: dnl You should have received a copy of the GNU Library General Public
   15: dnl License along with the GNU LIBICONV Library; see the file COPYING.LIB.
   16: dnl If not, write to the Free Software Foundation, Inc., 51 Franklin Street,
   17: dnl Fifth Floor, Boston, MA 02110-1301, USA.
   18: 
   19: AC_PREREQ([2.60])
   20: AC_INIT
   21: AC_CONFIG_SRCDIR([lib/iconv.c])
   22: AC_CONFIG_AUX_DIR([build-aux])
   23: AM_INIT_AUTOMAKE([libiconv], [1.13.1])
   24: AC_CONFIG_HEADERS([config.h lib/config.h])
   25: AC_PROG_MAKE_SET
   26: 
   27: dnl           checks for basic programs
   28: 
   29: AC_PROG_CC
   30: AC_PROG_CPP
   31: AC_PROG_INSTALL
   32: 
   33: AC_PATH_PROG([STRIP], [strip], [:]) dnl sets STRIP
   34: AM_PROG_INSTALL_STRIP               dnl overrides STRIP when cross-compiling,
   35:                                     dnl sets INSTALL_STRIP_PROGRAM
   36: 
   37: dnl           check for host type
   38: 
   39: AC_CANONICAL_HOST
   40: 
   41: dnl           hack
   42: 
   43: dnl Hack to work around limitations of automake and error.m4 regarding LIBOBJS.
   44: dnl "srclib/Makefile.am:32: automatically discovered file `error.h' should not be explicitly mentioned"
   45: AC_DEFUN([my_SRCLIB_OBJ],[SRCLIBOBJS="$SRCLIBOBJS $1.$ac_objext"])
   46: AC_DEFUN([my_SRCLIB_REPLACE_FUNCS], [AC_CHECK_FUNCS([$1], , [my_SRCLIB_OBJ($ac_func)])])
   47: m4_pushdef([AC_LIBOBJ], m4_defn([my_SRCLIB_OBJ]))
   48: m4_pushdef([AC_REPLACE_FUNCS], m4_defn([my_SRCLIB_REPLACE_FUNCS]))
   49: 
   50: dnl           checks for UNIX variants that set DEFS
   51: 
   52: gl_EARLY
   53: 
   54: dnl           checks for installer options
   55: 
   56: gl_RELOCATABLE([srclib])
   57: 
   58: AC_ARG_ENABLE([extra-encodings],
   59:   [AC_HELP_STRING([--enable-extra-encodings],
   60:                   [add support for a few rarely used encodings])],
   61:   [AC_DEFINE([ENABLE_EXTRA], 1,
   62:              [Define to 1 to enable a few rarely used encodings.])
   63:    USE_EXTRA_ENCODINGS=yes],
   64:   [USE_EXTRA_ENCODINGS=no])
   65: AC_SUBST([USE_EXTRA_ENCODINGS])
   66: 
   67: dnl           checks for programs
   68: 
   69: CL_PROG_CP
   70: CL_PROG_LN
   71: AC_PROG_LN_S
   72: 
   73: dnl           checks for compiler output filename suffixes
   74: 
   75: AC_OBJEXT
   76: AC_EXEEXT
   77: 
   78: dnl           check for build configuration
   79: 
   80: LT_INIT([disable-static win32-dll])
   81: 
   82: dnl Prepares the libtool configuration for handling of Windows resources, and
   83: dnl sets the RC variable to a program that compiles Windows resource files.
   84: LT_LANG([Windows Resource])
   85: 
   86: dnl On mingw and Cygwin, we can activate special Makefile rules which add
   87: dnl version information to the executables.
   88: case "$host_os" in
   89:   mingw* | cygwin*) is_woe32=yes ;;
   90:   *) is_woe32=no ;;
   91: esac
   92: WOE32=$is_woe32
   93: AC_SUBST([WOE32])
   94: if test $WOE32 = yes; then
   95:   dnl Check for a program that compiles Windows resource files.
   96:   AC_CHECK_TOOL([WINDRES], [windres])
   97: fi
   98: 
   99: gl_VISIBILITY
  100: AM_ICONV
  101: AM_GNU_GETTEXT([external], [need-ngettext])
  102: 
  103: dnl           checks for typedefs
  104: 
  105: AC_TYPE_MBSTATE_T
  106: gt_TYPE_WCHAR_T
  107: 
  108: dnl           checks for header files, functions and declarations
  109: 
  110: if test "$am_cv_func_iconv" = yes -a -n "$am_cv_proto_iconv_arg1"; then
  111:   ICONV_CONST="const"
  112: else
  113:   ICONV_CONST=""
  114: fi
  115: AC_SUBST([ICONV_CONST])
  116: 
  117: if test $gt_cv_c_wchar_t = yes; then
  118:   HAVE_WCHAR_T=1
  119: else
  120:   HAVE_WCHAR_T=0
  121: fi
  122: AC_SUBST([HAVE_WCHAR_T])
  123: 
  124: AC_CHECK_FUNCS([getc_unlocked mbrtowc wcrtomb mbsinit setlocale])
  125: 
  126: dnl mbstate_t is used if HAVE_WCRTOMB || HAVE_MBRTOWC, see lib/loop_wchar.h.
  127: if test $ac_cv_func_wcrtomb = yes || test $ac_cv_func_mbrtowc = yes; then
  128:   USE_MBSTATE_T=1
  129: else
  130:   USE_MBSTATE_T=0
  131: fi
  132: AC_SUBST([USE_MBSTATE_T])
  133: 
  134: AC_CACHE_CHECK([whether <wchar.h> is standalone],
  135:   [gl_cv_header_wchar_h_standalone],
  136:   [AC_COMPILE_IFELSE([[#include <wchar.h>
  137: wchar_t w;]],
  138:     [gl_cv_header_wchar_h_standalone=yes],
  139:     [gl_cv_header_wchar_h_standalone=no])])
  140: if test $gl_cv_header_wchar_h_standalone = yes; then
  141:   BROKEN_WCHAR_H=0
  142: else
  143:   BROKEN_WCHAR_H=1
  144: fi
  145: AC_SUBST([BROKEN_WCHAR_H])
  146: 
  147: AC_REPLACE_FUNCS([memmove])
  148: 
  149: AM_LANGINFO_CODESET
  150: 
  151: AC_EILSEQ
  152: 
  153: CL_WORDS_LITTLEENDIAN
  154: 
  155: gl_INIT
  156: 
  157: dnl           hack
  158: 
  159: dnl End of hack to work around limitations of automake and error.m4.
  160: m4_popdef([AC_REPLACE_FUNCS])
  161: m4_popdef([AC_LIBOBJ])
  162: AC_SUBST([SRCLIBOBJS])
  163: 
  164: dnl Compilation on mingw and Cygwin needs special Makefile rules, because
  165: dnl 1. when we install a shared library, we must arrange to export
  166: dnl    auxiliary pointer variables for every exported variable,
  167: dnl 2. when we install a shared library and a static library simultaneously,
  168: dnl    the include file specifies __declspec(dllimport) and therefore we
  169: dnl    must arrange to define the auxiliary pointer variables for the
  170: dnl    exported variables _also_ in the static library.
  171: if test "$enable_shared" = yes; then
  172:   case "$host_os" in
  173:     mingw* | cygwin*) is_woe32dll=yes ;;
  174:     *) is_woe32dll=no ;;
  175:   esac
  176: else
  177:   is_woe32dll=no
  178: fi
  179: WOE32DLL=$is_woe32dll
  180: AC_SUBST([WOE32DLL])
  181: if test $is_woe32dll = yes; then
  182:   DLL_VARIABLE='__declspec (dllimport)'
  183: else
  184:   DLL_VARIABLE=
  185: fi
  186: AC_SUBST([DLL_VARIABLE])
  187: 
  188: AH_BOTTOM([
  189: /* On Windows, variables that may be in a DLL must be marked specially.  */
  190: #if defined _MSC_VER && defined _DLL
  191: # define DLL_VARIABLE __declspec (dllimport)
  192: #else
  193: # define DLL_VARIABLE
  194: #endif
  195: ])
  196: 
  197: AC_CONFIG_SUBDIRS([libcharset])
  198: AC_CONFIG_SUBDIRS([preload])
  199: AC_CONFIG_FILES([Makefile])
  200: AC_CONFIG_FILES([lib/Makefile])
  201: AC_CONFIG_FILES([srclib/Makefile])
  202: AC_CONFIG_FILES([src/Makefile])
  203: AC_CONFIG_FILES([po/Makefile.in])
  204: AC_CONFIG_FILES([man/Makefile])
  205: if test -d "${srcdir}/tests"; then
  206:   AC_CONFIG_FILES([tests/Makefile])
  207: fi
  208: AC_CONFIG_FILES([include/iconv.h:include/iconv.h.build.in])
  209: AC_CONFIG_FILES([include/iconv.h.inst:include/iconv.h.in])
  210: AC_OUTPUT