Annotation of embedaddon/libiconv/djgpp/config.sed, revision 1.1.1.1
1.1 misho 1: # DJGPP specific configuration file.
2: # Sed script for additional DJGPP specific editing
3: # of the configure script generated by autoconf 2.60.
4:
5:
6: # Additional editing of Makefiles
7: /^".*ac_file_inputs.*tmp\/out$/ a\
8: cat > "$tmp/subs-djgpp.sed" << eof_djgpp\
9: # DJGPP specific Makefile changes.\
10: s,\\.deps,_deps,g\
11: s,\\.libs,_libs,g\
12: s,\\.new\\.,_new.,g\
13: s,\\.old\\.,_old.,g\
14: s,\\.tab\\.,_tab.,g\
15: s,config\\.h\\.in,config.h-in,g\
16: s,\\.\\([1-9]\\)\\.html,_\\1.html,g\
17: s,iconv\\.h\\.inst,iconv_h.ins,g\
18: s,iconv\\.h\\.in,iconv.h-in,g\
19: s,iconv\\.h\\.build\\.in,iconv.h-build-in,g\
20: s,libcharset\\.h\\.in,libcharset.h-in,g\
21: s,localcharset\\.h\\.inst,localcharset_h.ins,g\
22: s,localcharset\\.h\\.in,localcharset.h-in,g\
23: s,localcharset\\.h\\.build\\.in,localcharset.h-build-in,g\
24: s,Makefile\\.am\\.in,Makefile.am-in,g\
25: s,Makefile\\.in\\.in,Makefile.in-in,g\
26: /^\\.y\\.c:/,/^$/ {\
27: /\\\$(YACCCOMPILE)/ {\
28: a\\\\\
29: -@test -f y.tab.c && mv -f y.tab.c y_tab.c\\\\\
30: -@test -f y.tab.h && mv -f y.tab.h y_tab.h\
31: }\
32: }\
33: eof_djgpp\
34: sed -f "\$tmp/subs-djgpp.sed" \$tmp/out > \$tmp/out.djgpp\
35: mv -f \$tmp/out.djgpp \$tmp/out
36:
37:
38: # Rename config.h.in into config.h-in
39: /ac_config_headers=/s|config\.h|&:config.h-in|g
40: /CONFIG_HEADERS=/ s|config\.h\.in|&:config.h-in|2
41:
42: # Rename iconv.h.build.in, iconv.h.inst, iconv.h.in and Makefile.in.in into iconv.h-build-in, iconv_h.ins, iconv.h-in and Makefile.in-in
43: /ac_config_files=/ {
44: s|iconv\.h\.build\.in|iconv.h-build-in|
45: s|iconv\.h\.inst|iconv_h.ins|
46: s|iconv\.h\.in|iconv.h-in|
47: s|po/Makefile\.in|&:po/Makefile.in-in|
48: }
49: /CONFIG_FILES=/ {
50: s|iconv\.h\.build\.in|iconv.h-build-in|
51: s|iconv\.h\.inst|iconv_h.ins|
52: s|iconv\.h\.in|iconv.h-in|
53: s|po/Makefile\.in|&:po/Makefile.in-in|2
54: }
55:
56: # Rename localcharset.h.build.in, localcharset.h.inst, localcharset.h.in and Makefile.in.in into localcharset.h-build-in, localcharset_h.ins, localcharset.h-in and Makefile.in-in
57: /ac_config_files=/ {
58: s|localcharset\.h\.build\.in|localcharset.h-build-in|
59: s|localcharset\.h\.inst|localcharset_h.ins|
60: s|localcharset\.h\.in|localcharset.h-in|
61: }
62: /CONFIG_FILES=/ {
63: s|localcharset\.h\.build\.in|localcharset.h-build-in|
64: s|localcharset\.h\.inst|localcharset_h.ins|
65: s|localcharset\.h\.in|localcharset.h-in|
66: }
67:
68: # We always use _deps and _libs instead of .deps and .libs, because
69: # the latter is an invalid name on 8+3 MS-DOS file system. This makes
70: # the generated Makefiles good for every DJGPP installation, not only
71: # the one where the package was configured (which could happen to be
72: # a Windows box, where leading dots in file names are allowed).
73: s,\.deps,_deps,g
74: s,\.libs,_libs,g
75: /^rmdir[ ]*\.tst/ i\
76: am__leading_dot=_
77:
78: # Replace (command) > /dev/null with `command > /dev/null`, since
79: # parenthesized commands always return zero status in the ported Bash,
80: # even if the named command doesn't exist
81: /if ([^|;`]*null/{
82: s,(,`,
83: s,),,
84: /null[ ]*2>&1/ s,2>&1,&`,
85: /null.*null/ s,null.*null,&`,
86: /null.*null/ !{
87: /null[ ]*2>&1/ !s,null,&`,
88: }
89: }
90:
91: # DOS-style absolute file names should be supported as well
92: /\*) top_srcdir=/s,/\*,[\\\\/]* | ?:[\\\\/]*,
93:
94: # The following two items are changes needed for configuring
95: # and compiling across partitions.
96: # 1) The given srcdir value is always translated from the
97: # "x:" syntax into "/dev/x" syntax while we run configure.
98: /^[ ]*-srcdir=\*.*$/ a\
99: ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
100: /set X `ls -Lt \$srcdir/ i\
101: if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
102: srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
103: fi
104:
105: # Autoconf 2.52e generated configure scripts
106: # write absolute paths into Makefiles and bison.in
107: # making them useless for DJGPP installations for
108: # which the package has not been configured for.
109: /MISSING=/,/^$/ {
110: /^fi$/ a\
111: am_missing_run=`echo "$am_missing_run" | sed 's%/dev/.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%;s%.:.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%'`
112: }
113: /^install_sh=/a\
114: install_sh=`echo "$install_sh" | sed 's%/dev/.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%;s%.:.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%'`
115:
116: # This will only work if the assumption that the
117: # testsuite is ran from the following path:
118: # ${top_srcdir}/tests/testsuite.dir
119: # holds. The explicit names are of no importance.
120: # ../../. == ${top_srcdir}
121: #/^esac$/,/^ac_abs_srcdir=/ {
122: /^ac_abs_srcdir=/ i\
123: ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%/dev/.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`\
124: ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%/dev/.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`\
125: ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%/dev/.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`
126: #ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%/dev/.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/libiconv[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`
127: /^ac_abs_srcdir=/ a\
128: for dj_dir in $ac_abs_builddir $ac_abs_top_builddir $ac_abs_top_srcdir $ac_abs_srcdir\
129: do\
130: ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%//%/%g"`\
131: ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%//%/%g"`\
132: ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%//%/%g"`\
133: ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%//%/%g"`\
134: done
135:
136: # Add DJGPP version information.
137: /^#define VERSION/ s/\$VERSION/& (DJGPP port (r1))/
138:
139: # We need makeinfo to make the html formated docs.
140: /\$am_missing_run[ ]*makeinfo/ s,\$am_missing_run,,
141:
142: # The path to the FORTRAN compiler and libraries
143: # shall contain no absolute path reference so it
144: # will be good for all djgpp installations.
145: /^FLIBS="\$ac_cv_flibs"/ i\
146: ac_djgpp_path=`echo "$DJDIR" | sed 's%\\\\\\%/%g' | tr $as_cr_LETTERS $as_cr_letters`\
147: ac_cv_flibs=`echo "$ac_cv_flibs" | sed "s%-L$ac_djgpp_path%-L/dev/env/DJDIR%g"`
148:
149: # Autoconf generated configure scripts write absolute
150: # paths of certain header files into Makefiles making
151: # them useless for DJGPP installations for which the
152: # package has not been configured for.
153: /^.*echo "\$as_me:\$LINENO: result: \$gl_cv_absolute_.*$/ {
154: h
155: s,^.*\(gl_cv_absolute_\)\([a-z0-9_]*\)\(_h\).*$,\1\2\3=`echo $\1\2\3 | sed "s%[^:]:.*/include/%/dev/env/DJDIR/include/%"`,
156: G
157: }
158: /^.*echo "\$as_me:\$LINENO: result: \$gl_cv_full_.*$/ {
159: h
160: s,^.*\(gl_cv_full_\)\([a-z0-9_]*\)\(_h\).*$,\1\2\3=`echo $\1\2\3 | sed "s%[^:]:.*/include/%/dev/env/DJDIR/include/%"`,
161: G
162: }
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/cvsweb/back.gif){kind=icon}
Return to config.sed CVS log ![[TXT]](/icons/cvsweb/text.gif){kind=icon}
![[DIR]](/icons/cvsweb/dir.gif){kind=icon}
Up to [ELWIX - Embedded LightWeight unIX -] / embedaddon / libiconv / djgpp