Annotation of embedaddon/libiconv/srcm4/size_max.m4, revision 1.1
1.1 ! misho 1: # size_max.m4 serial 9
! 2: dnl Copyright (C) 2003, 2005-2006, 2008-2009 Free Software Foundation, Inc.
! 3: dnl This file is free software; the Free Software Foundation
! 4: dnl gives unlimited permission to copy and/or distribute it,
! 5: dnl with or without modifications, as long as this notice is preserved.
! 6:
! 7: dnl From Bruno Haible.
! 8:
! 9: AC_DEFUN([gl_SIZE_MAX],
! 10: [
! 11: AC_CHECK_HEADERS([stdint.h])
! 12: dnl First test whether the system already has SIZE_MAX.
! 13: AC_CACHE_CHECK([for SIZE_MAX], [gl_cv_size_max], [
! 14: gl_cv_size_max=
! 15: AC_EGREP_CPP([Found it], [
! 16: #include <limits.h>
! 17: #if HAVE_STDINT_H
! 18: #include <stdint.h>
! 19: #endif
! 20: #ifdef SIZE_MAX
! 21: Found it
! 22: #endif
! 23: ], [gl_cv_size_max=yes])
! 24: if test -z "$gl_cv_size_max"; then
! 25: dnl Define it ourselves. Here we assume that the type 'size_t' is not wider
! 26: dnl than the type 'unsigned long'. Try hard to find a definition that can
! 27: dnl be used in a preprocessor #if, i.e. doesn't contain a cast.
! 28: AC_COMPUTE_INT([size_t_bits_minus_1], [sizeof (size_t) * CHAR_BIT - 1],
! 29: [#include <stddef.h>
! 30: #include <limits.h>], [size_t_bits_minus_1=])
! 31: AC_COMPUTE_INT([fits_in_uint], [sizeof (size_t) <= sizeof (unsigned int)],
! 32: [#include <stddef.h>], [fits_in_uint=])
! 33: if test -n "$size_t_bits_minus_1" && test -n "$fits_in_uint"; then
! 34: if test $fits_in_uint = 1; then
! 35: dnl Even though SIZE_MAX fits in an unsigned int, it must be of type
! 36: dnl 'unsigned long' if the type 'size_t' is the same as 'unsigned long'.
! 37: AC_TRY_COMPILE([#include <stddef.h>
! 38: extern size_t foo;
! 39: extern unsigned long foo;
! 40: ], [], [fits_in_uint=0])
! 41: fi
! 42: dnl We cannot use 'expr' to simplify this expression, because 'expr'
! 43: dnl works only with 'long' integers in the host environment, while we
! 44: dnl might be cross-compiling from a 32-bit platform to a 64-bit platform.
! 45: if test $fits_in_uint = 1; then
! 46: gl_cv_size_max="(((1U << $size_t_bits_minus_1) - 1) * 2 + 1)"
! 47: else
! 48: gl_cv_size_max="(((1UL << $size_t_bits_minus_1) - 1) * 2 + 1)"
! 49: fi
! 50: else
! 51: dnl Shouldn't happen, but who knows...
! 52: gl_cv_size_max='((size_t)~(size_t)0)'
! 53: fi
! 54: fi
! 55: ])
! 56: if test "$gl_cv_size_max" != yes; then
! 57: AC_DEFINE_UNQUOTED([SIZE_MAX], [$gl_cv_size_max],
! 58: [Define as the maximum value of type 'size_t', if the system doesn't define it.])
! 59: fi
! 60: dnl Don't redefine SIZE_MAX in config.h if config.h is re-included after
! 61: dnl <stdint.h>. Remember that the #undef in AH_VERBATIM gets replaced with
! 62: dnl #define by AC_DEFINE_UNQUOTED.
! 63: AH_VERBATIM([SIZE_MAX],
! 64: [/* Define as the maximum value of type 'size_t', if the system doesn't define
! 65: it. */
! 66: #ifndef SIZE_MAX
! 67: # undef SIZE_MAX
! 68: #endif])
! 69: ])
! 70:
! 71: dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
! 72: dnl Remove this when we can assume autoconf >= 2.61.
! 73: m4_ifdef([AC_COMPUTE_INT], [], [
! 74: AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
! 75: ])
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>