1: cmake_minimum_required(VERSION 3.12 FATAL_ERROR)
2:
3: project (miniupnpc
4: VERSION 2.2.5
5: DESCRIPTION "UPnP IGD client lightweight library"
6: HOMEPAGE_URL https://miniupnp.tuxfamily.org/
7: LANGUAGES C)
8:
9: set (MINIUPNPC_API_VERSION 17)
10:
11: option (UPNPC_BUILD_STATIC "Build static library" TRUE)
12: option (UPNPC_BUILD_SHARED "Build shared library" TRUE)
13: option (UPNPC_BUILD_TESTS "Build test executables" TRUE)
14: option (UPNPC_BUILD_SAMPLE "Build sample executables" TRUE)
15: option (NO_GETADDRINFO "Define NO_GETADDRINFO" FALSE)
16: option (UPNPC_NO_INSTALL "Disable installation" FALSE)
17:
18: if (NOT UPNPC_BUILD_STATIC AND NOT UPNPC_BUILD_SHARED)
19: message (FATAL "Both shared and static libraries are disabled!")
20: endif ()
21:
22: include(GNUInstallDirs)
23:
24: # Interface library for compile definitions, flags and option
25: add_library(miniupnpc-private INTERFACE)
26:
27: if (NO_GETADDRINFO)
28: target_compile_definitions(miniupnpc-private INTERFACE NO_GETADDRINFO)
29: endif ()
30:
31: if (NOT WIN32)
32: target_compile_definitions(miniupnpc-private INTERFACE
33: MINIUPNPC_SET_SOCKET_TIMEOUT
34: _BSD_SOURCE _DEFAULT_SOURCE)
35: if (NOT APPLE AND NOT CMAKE_SYSTEM_NAME MATCHES ".*BSD" AND NOT CMAKE_SYSTEM_NAME STREQUAL "SunOS")
36: # add_definitions (-D_POSIX_C_SOURCE=200112L)
37: target_compile_definitions(miniupnpc-private INTERFACE _XOPEN_SOURCE=600)
38: endif ()
39: if (CMAKE_SYSTEM_NAME STREQUAL "NetBSD")
40: target_compile_definitions(miniupnpc-private INTERFACE _NETBSD_SOURCE)
41: endif ()
42: else ()
43: target_compile_definitions(miniupnpc-private INTERFACE _WIN32_WINNT=0x0501) # XP or higher for getnameinfo and friends
44: endif ()
45:
46: if (APPLE)
47: target_compile_definitions(miniupnpc-private INTERFACE _DARWIN_C_SOURCE)
48: endif ()
49:
50: # Set compiler specific build flags
51: if (CMAKE_COMPILER_IS_GNUCC AND NOT CMAKE_SYSTEM_NAME STREQUAL "AmigaOS")
52: set(CMAKE_POSITION_INDEPENDENT_CODE ON)
53: target_compile_options(miniupnpc-private INTERFACE -Wall)
54: endif ()
55:
56: # Suppress noise warnings
57: if (MSVC)
58: target_compile_definitions(miniupnpc-private INTERFACE _CRT_SECURE_NO_WARNINGS _WINSOCK_DEPRECATED_NO_WARNINGS)
59: endif()
60:
61: configure_file (${CMAKE_CURRENT_SOURCE_DIR}/miniupnpcstrings.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/miniupnpcstrings.h)
62: target_include_directories(miniupnpc-private INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>)
63:
64: set (MINIUPNPC_SOURCES
65: src/igd_desc_parse.c
66: src/miniupnpc.c
67: src/minixml.c
68: src/minisoap.c
69: src/minissdpc.c
70: src/miniwget.c
71: src/upnpcommands.c
72: src/upnpdev.c
73: src/upnpreplyparse.c
74: src/upnperrors.c
75: src/connecthostport.c
76: src/portlistingparse.c
77: src/receivedata.c
78: src/addr_is_reserved.c
79: ${CMAKE_CURRENT_BINARY_DIR}/miniupnpcstrings.h
80: )
81:
82: if (WIN32)
83: target_link_libraries(miniupnpc-private INTERFACE ws2_32 iphlpapi)
84: elseif (CMAKE_SYSTEM_NAME STREQUAL "SunOS")
85: target_link_libraries(miniupnpc-private INTERFACE socket nsl resolv)
86: find_library (SOCKET_LIBRARY NAMES socket)
87: find_library (NSL_LIBRARY NAMES nsl)
88: find_library (RESOLV_LIBRARY NAMES resolv)
89: set (LDLIBS ${SOCKET_LIBRARY} ${NSL_LIBRARY} ${RESOLV_LIBRARY} ${LDLIBS})
90: elseif (HAIKU)
91: target_link_libraries(miniupnpc-private INTERFACE network)
92: find_library (SOCKET_LIBRARY NAMES network)
93: find_library (NSL_LIBRARY NAMES network)
94: find_library (RESOLV_LIBRARY NAMES network)
95: set (LDLIBS ${SOCKET_LIBRARY} ${NSL_LIBRARY} ${RESOLV_LIBRARY} ${LDLIBS})
96: endif ()
97:
98:
99: if (UPNPC_BUILD_STATIC)
100: add_library (libminiupnpc-static STATIC ${MINIUPNPC_SOURCES})
101: target_include_directories (libminiupnpc-static PUBLIC
102: $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
103: $<INSTALL_INTERFACE:include/miniupnpc>)
104: if (NOT UPNPC_BUILD_SHARED)
105: add_library (miniupnpc::miniupnpc ALIAS libminiupnpc-static)
106: endif()
107: set_target_properties (libminiupnpc-static PROPERTIES EXPORT_NAME miniupnpc)
108: if (WIN32 AND NOT MINGW)
109: set_target_properties (libminiupnpc-static PROPERTIES OUTPUT_NAME "libminiupnpc")
110: else()
111: set_target_properties (libminiupnpc-static PROPERTIES OUTPUT_NAME "miniupnpc")
112: endif()
113: target_link_libraries (libminiupnpc-static PRIVATE miniupnpc-private)
114: target_include_directories(libminiupnpc-static INTERFACE $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
115: target_compile_definitions(libminiupnpc-static PUBLIC MINIUPNP_STATICLIB)
116:
117: if (NOT UPNPC_NO_INSTALL)
118: install (TARGETS miniupnpc-private EXPORT miniupnpc-private)
119:
120: install (EXPORT miniupnpc-private
121: DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/miniupnpc"
122: NAMESPACE miniupnpc::)
123:
124: install (TARGETS libminiupnpc-static
125: EXPORT libminiupnpc-static
126: RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
127: LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
128: ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
129:
130: install (EXPORT libminiupnpc-static
131: DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/miniupnpc"
132: NAMESPACE miniupnpc::)
133: endif()
134:
135: if (UPNPC_BUILD_SAMPLE)
136: add_executable (upnpc-static src/upnpc.c)
137: target_link_libraries (upnpc-static PRIVATE libminiupnpc-static)
138: target_include_directories(upnpc-static PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
139: if (NOT UPNPC_NO_INSTALL)
140: install (TARGETS upnpc-static
141: RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
142: endif()
143: endif ()
144: endif ()
145:
146: if (UPNPC_BUILD_SHARED)
147: add_library (libminiupnpc-shared SHARED ${MINIUPNPC_SOURCES})
148: target_include_directories (libminiupnpc-shared PUBLIC
149: $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
150: $<INSTALL_INTERFACE:include/miniupnpc>)
151: add_library (miniupnpc::miniupnpc ALIAS libminiupnpc-shared)
152: set_target_properties (libminiupnpc-shared PROPERTIES EXPORT_NAME miniupnpc)
153: set_target_properties (libminiupnpc-shared PROPERTIES OUTPUT_NAME "miniupnpc")
154: set_target_properties (libminiupnpc-shared PROPERTIES VERSION ${PROJECT_VERSION})
155: set_target_properties (libminiupnpc-shared PROPERTIES SOVERSION ${MINIUPNPC_API_VERSION})
156: target_link_libraries (libminiupnpc-shared PRIVATE miniupnpc-private)
157: target_compile_definitions(libminiupnpc-shared PRIVATE MINIUPNP_EXPORTS)
158:
159: target_include_directories(libminiupnpc-shared INTERFACE $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>)
160: if (WIN32)
161: target_link_libraries(libminiupnpc-shared INTERFACE ws2_32 iphlpapi)
162: endif()
163:
164: if (NOT UPNPC_NO_INSTALL)
165: install (TARGETS libminiupnpc-shared
166: EXPORT libminiupnpc-shared
167: RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
168: LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
169: ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
170:
171: install (EXPORT libminiupnpc-shared
172: DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/miniupnpc"
173: NAMESPACE miniupnpc::)
174: endif()
175:
176: if (UPNPC_BUILD_SAMPLE)
177: add_executable (upnpc-shared src/upnpc.c)
178: target_link_libraries (upnpc-shared PRIVATE libminiupnpc-shared)
179: target_include_directories(upnpc-shared PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
180: if (NOT UPNPC_NO_INSTALL)
181: install (TARGETS upnpc-shared
182: RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
183: endif()
184: endif ()
185:
186: add_executable (listdevices src/listdevices.c)
187: target_link_libraries (listdevices PRIVATE libminiupnpc-shared)
188: target_include_directories(listdevices PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
189: if (NOT UPNPC_NO_INSTALL)
190: install (TARGETS listdevices
191: RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
192: endif()
193: endif ()
194:
195: if (UPNPC_BUILD_TESTS)
196: add_library(miniupnpc-tests INTERFACE)
197: target_link_libraries(miniupnpc-tests INTERFACE miniupnpc-private)
198: target_compile_definitions(miniupnpc-tests INTERFACE MINIUPNP_STATICLIB)
199:
200: add_executable (testminixml src/testminixml.c src/minixml.c src/igd_desc_parse.c)
201: target_include_directories (testminixml PRIVATE
202: $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
203: target_link_libraries (testminixml PRIVATE miniupnpc-tests)
204:
205: add_executable (minixmlvalid src/minixmlvalid.c src/minixml.c)
206: target_link_libraries (minixmlvalid PRIVATE miniupnpc-tests)
207:
208: add_executable (testupnpreplyparse src/testupnpreplyparse.c
209: src/minixml.c src/upnpreplyparse.c)
210: target_include_directories (testupnpreplyparse PRIVATE
211: $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
212: target_link_libraries (testupnpreplyparse PRIVATE miniupnpc-tests)
213:
214: add_executable (testigddescparse src/testigddescparse.c
215: src/igd_desc_parse.c src/minixml.c src/miniupnpc.c src/miniwget.c src/minissdpc.c
216: src/upnpcommands.c src/upnpreplyparse.c src/minisoap.c src/connecthostport.c
217: src/portlistingparse.c src/receivedata.c src/addr_is_reserved.c
218: )
219: target_include_directories (testigddescparse PRIVATE
220: $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
221: target_link_libraries (testigddescparse PRIVATE miniupnpc-tests)
222:
223: add_executable (testminiwget src/testminiwget.c
224: src/miniwget.c src/miniupnpc.c src/minisoap.c src/upnpcommands.c src/minissdpc.c
225: src/upnpreplyparse.c src/minixml.c src/igd_desc_parse.c src/connecthostport.c
226: src/portlistingparse.c src/receivedata.c src/addr_is_reserved.c
227: )
228: target_include_directories (testminiwget PRIVATE
229: $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
230: target_link_libraries (testminiwget PRIVATE miniupnpc-tests)
231:
232: add_executable (testaddr_is_reserved src/testaddr_is_reserved.c
233: src/addr_is_reserved.c
234: )
235: target_link_libraries (testaddr_is_reserved PRIVATE miniupnpc-tests)
236:
237: add_executable (testportlistingparse src/testportlistingparse.c
238: src/minixml.c src/portlistingparse.c)
239: target_include_directories (testportlistingparse PRIVATE
240: $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>)
241: target_link_libraries (testportlistingparse PRIVATE miniupnpc-tests)
242:
243: add_executable (minihttptestserver src/minihttptestserver.c)
244:
245: # set (UPNPC_INSTALL_TARGETS ${UPNPC_INSTALL_TARGETS} testminixml minixmlvalid testupnpreplyparse testigddescparse testminiwget)
246: include(CTest)
247: add_test(NAME validateminixml
248: COMMAND minixmlvalid)
249: add_test(NAME validateminiwget
250: COMMAND ${CMAKE_SOURCE_DIR}/testminiwget.sh)
251: set_property(TEST validateminiwget
252: PROPERTY ENVIRONMENT
253: TESTSERVER=${CMAKE_BINARY_DIR}/minihttptestserver
254: TESTMINIWGET=${CMAKE_BINARY_DIR}/testminiwget)
255: add_test(NAME validateupnpreplyparse
256: COMMAND ${CMAKE_SOURCE_DIR}/testupnpreplyparse.sh
257: WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
258: set_property(TEST validateupnpreplyparse
259: PROPERTY ENVIRONMENT
260: TESTUPNPREPLYPARSE=${CMAKE_BINARY_DIR}/testupnpreplyparse)
261: add_test(NAME validateportlistingparse
262: COMMAND testportlistingparse)
263: add_test(NAME validateigddescparse1
264: COMMAND testigddescparse new_LiveBox_desc.xml new_LiveBox_desc.values
265: WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/testdesc)
266: add_test(NAME validateigddescparse2
267: COMMAND testigddescparse linksys_WAG200G_desc.xml linksys_WAG200G_desc.values
268: WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/testdesc)
269: add_test(NAME validateaddr_is_reserved
270: COMMAND testaddr_is_reserved)
271:
272: endif ()
273:
274: configure_file(miniupnpc.pc.in miniupnpc.pc @ONLY)
275:
276: if (NOT UPNPC_NO_INSTALL)
277: install (FILES
278: include/miniupnpc.h
279: include/miniwget.h
280: include/upnpcommands.h
281: include/igd_desc_parse.h
282: include/upnpreplyparse.h
283: include/upnperrors.h
284: include/upnpdev.h
285: include/miniupnpctypes.h
286: include/portlistingparse.h
287: include/miniupnpc_declspec.h
288: DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/miniupnpc
289: )
290:
291: install(FILES miniupnpc-config.cmake
292: DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/miniupnpc
293: )
294:
295: install(FILES ${CMAKE_CURRENT_BINARY_DIR}/miniupnpc.pc
296: DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig
297: )
298:
299: install(FILES man3/miniupnpc.3
300: DESTINATION ${CMAKE_INSTALL_MANDIR}/man3
301: )
302:
303: install(FILES external-ip.sh
304: TYPE BIN
305: )
306: endif()
307:
308: # vim: ts=2:sw=2:expandtab
FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>
![[BACK]](/icons/cvsweb/back.gif){kind=icon}
Return to CMakeLists.txt CVS log ![[TXT]](/icons/cvsweb/text.gif){kind=icon}
![[DIR]](/icons/cvsweb/dir.gif){kind=icon}
Up to [ELWIX - Embedded LightWeight unIX -] / embedaddon / miniupnpc