Return to configure.in CVS log

Up to [ELWIX - Embedded LightWeight unIX -] / libaitcli

Version 4.6

#
# $Author: misho $
# $Id: configure.in,v 1.23 2025/12/17 23:30:11 misho Exp $
#
AC_INIT(libaitcli, 4.6, misho@elwix.org)
AC_CONFIG_SRCDIR([src/aitcli.c])
AC_CONFIG_HEADERS([inc/config.h])

ac_cv_func_malloc_0_nonnull="yes"
ac_cv_func_realloc_0_nonnull="yes"

# Checks for programs.
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_RANLIB

AC_CANONICAL_HOST
AC_CANONICAL_TARGET

AC_CHECK_TOOL(MKDEP, mkdep, ../mkdep)
AC_SUBST(MKDEP)

if test x"${prefix}" = x"NONE"; then
	prefix="/usr/local"
fi
if test x"${exec_prefix}" = x"NONE"; then
	exec_prefix=${prefix}
fi

if test "${ac_cv_env_CFLAGS_set}" != "set"; then
	CFLAGS="-Wall -O2 -I${includedir}"
else
	CFLAGS="${ac_cv_env_CFLAGS_value}"
fi
if test "${ac_cv_env_LDFLAGS_set}" = "set"; then
	LDFLAGS="${ac_cv_env_LDFLAGS_value}"
else
	LDFLAGS="-L$(eval echo ${libdir})"
fi


# Checks for libraries.
AC_CHECK_LIB(util, [forkpty])
AC_CHECK_LIB(elwix, [str_Trim])

# Checks for header files.
AC_CHECK_HEADERS([stdlib.h string.h sys/ioctl.h termios.h unistd.h libutil.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE

# Checks for library functions.
AC_CHECK_FUNCS([memset strdup strerror])
AC_CHECK_FUNCS([str_Trim])
AC_CHECK_FUNCS([forkpty])

DEBUG=no
AC_MSG_CHECKING(Debug Build)
AC_ARG_ENABLE(debug,
	[  --enable-debug          Build library with debug information and additional messages],
	[ DEBUG=$enableval
		case "$enableval" in
			yes)
				AC_DEFINE(__DEBUG,, [Build libraries with debug information and additional messages])
				CFLAGS="-g ${CFLAGS}"
				;;
			*)
				AC_DEFINE(NDEBUG,, [Turn off debug asserts])
				;;
		esac ], AC_DEFINE(NDEBUG,, [Turn off debug asserts]))
AC_MSG_RESULT($DEBUG)

DEBIAN_ARCH=$target_cpu
AS_IF([ test "x$target_cpu" = "xarm6l" -o "x$target_cpu" = "xarm7l" ], DEBIAN_ARCH="armhf") 
AS_IF([ test "x$target_cpu" = "xaarch64" ], DEBIAN_ARCH="arm64") 
AS_IF([ test "x$target_cpu" = "xi686" ], DEBIAN_ARCH="i386") 
AS_IF([ test "x$target_cpu" = "xx86_64" ], DEBIAN_ARCH="amd64") 
AC_SUBST(DEBIAN_ARCH)

AC_CONFIG_FILES([Makefile
		inc/Makefile
		lib/Makefile
		debian/Makefile
		debian/control
		src/Makefile])
AC_OUTPUT