File:  [ELWIX - Embedded LightWeight unIX -] / libelwix / configure.in
Revision 1.45: download - view: text, annotated - select for diffs - revision graph
Tue Jun 26 14:39:13 2018 UTC (5 years, 9 months ago) by misho
Branches: MAIN
CVS tags: elwix4_16, HEAD, ELWIX4_15
adds new function in json support

#
# $Author: misho $
# $Id: configure.in,v 1.45 2018/06/26 14:39:13 misho Exp $
#
AC_INIT(libelwix, 4.15, misho@elwix.org)
AC_CONFIG_SRCDIR([src/elwix.c])
AC_CONFIG_HEADERS([inc/config.h])

ac_cv_func_malloc_0_nonnull="yes"
ac_cv_func_realloc_0_nonnull="yes"

# Checks for programs.
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_RANLIB

AC_CANONICAL_HOST
AC_CANONICAL_TARGET

AC_CHECK_TOOL(MKDEP, mkdep, ../mkdep)
AC_SUBST(MKDEP)

CFLAGS="-Wall -O2 -fPIC ${CFLAGS}"
LDFLAGS="${LDFLAGS}"

AC_CHECK_LIB([pthread], [pthread_mutex_init])

# Checks for header files.
AC_CHECK_HEADERS([stdlib.h string.h sys/ioctl.h termios.h unistd.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_INLINE

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_REALLOC
AC_CHECK_FUNCS([memset regcomp strchr strerror link_addr])

DEBUG=no
AC_MSG_CHECKING(Debug Build)
AC_ARG_ENABLE(debug,
	[  --enable-debug          Build library with debug information and additional messages],
	[ DEBUG=$enableval
		case "$enableval" in
			yes)
				CFLAGS="-g ${CFLAGS}"
				;;
			*)
				AC_DEFINE(NDEBUG,, [Build w/o assert() support])
				;;
		esac ],)
AC_MSG_RESULT($DEBUG)

MEMMGR="elwix"
AC_MSG_CHECKING(Memory management)
AC_ARG_WITH(memmgr,
	[  --with-memmgr=<mm>      Memory manager for ELWIX (elwix|system)], 
	[ case "$withval" in
		sys|system)
			MEMMGR="system"
			AC_DEFINE(MEMMGR, ELWIX_SYSM, [ELWIX memory manager])
			;;
		*)
			MEMMGR="elwix"
			AC_DEFINE(MEMMGR, ELWIX_MPOOL, [ELWIX memory manager])
			;;
	  esac ], AC_DEFINE(MEMMGR, ELWIX_MPOOL, [ELWIX memory manager]))
AC_MSG_RESULT($MEMMGR)

AC_CONFIG_FILES([Makefile
                 inc/Makefile
                 lib/Makefile
                 src/Makefile])
AC_OUTPUT

FreeBSD-CVSweb <freebsd-cvsweb@FreeBSD.org>