#
# $Author: misho $
# $Id: configure.in,v 1.33 2025/01/31 00:03:15 misho Exp $
#
AC_INIT(libaitcfg, 9.5, misho@elwix.org)
AC_CONFIG_SRCDIR([src/aitcfg.c])
AC_CONFIG_HEADERS([inc/config.h])

ac_cv_func_malloc_0_nonnull="yes"
ac_cv_func_realloc_0_nonnull="yes"

# Checks for programs.
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_RANLIB

AC_CANONICAL_HOST
AC_CANONICAL_TARGET

AC_CHECK_TOOL(MKDEP, mkdep, ../mkdep)
AC_SUBST(MKDEP)

if test x"${prefix}" = x"NONE"; then
	prefix="/usr/local"
fi
if test x"${exec_prefix}" = x"NONE"; then
	exec_prefix=${prefix}
fi

if test "${ac_cv_env_CFLAGS_set}" != "set"; then
	CFLAGS="-Wall -O2 -I${includedir}"
else
	CFLAGS="${ac_cv_env_CFLAGS_value}"
fi
if test "${ac_cv_env_LDFLAGS_set}" = "set"; then
	LDFLAGS="${ac_cv_env_LDFLAGS_value}"
else
	LDFLAGS="-L$(eval echo ${libdir})"
fi


# Checks for libraries.
AC_CHECK_LIB([pthread], [pthread_mutex_lock])
AC_CHECK_LIB([elwix], [str_Trim])

# Checks for header files.
AC_CHECK_HEADERS([stdint.h stdlib.h string.h unistd.h])
AC_CHECK_HEADERS([bsd/string.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE

# Checks for library functions.
AC_FUNC_MALLOC
AC_FUNC_REALLOC
AC_CHECK_FUNCS([memmove memset strchr strspn])

DEBUG=no
AC_MSG_CHECKING(Debug Build)
AC_ARG_ENABLE(debug,
	[  --enable-debug          Build library with debug information and additional messages],
	[ DEBUG=$enableval
		case "$enableval" in
			yes)
				AC_DEFINE(__DEBUG,, [Build libraries with debug information and additional messages])
				CFLAGS="-g ${CFLAGS}"
				;;
			*)
				AC_DEFINE(NDEBUG,, [Turn off debug asserts])
				;;
		esac ], AC_DEFINE(NDEBUG,, [Turn off debug asserts]))
AC_MSG_RESULT($DEBUG)

DEBIAN_ARCH=$target_cpu
AS_IF([ test "x$target_cpu" = "xarm6l" -o "x$target_cpu" = "xarm7l" ], DEBIAN_ARCH="armhf") 
AS_IF([ test "x$target_cpu" = "xaarch64" ], DEBIAN_ARCH="arm64") 
AS_IF([ test "x$target_cpu" = "xi686" ], DEBIAN_ARCH="i386") 
AS_IF([ test "x$target_cpu" = "xx86_64" ], DEBIAN_ARCH="amd64") 
AC_SUBST(DEBIAN_ARCH)

AC_CONFIG_FILES([Makefile
		bin/Makefile
		inc/Makefile
		lib/Makefile
		debian/Makefile
		debian/control
		src/Makefile])
AC_OUTPUT